PRO sounding

	;Tell IDL the name of the file that has our data
	file = 'KGRB.txt'

	;Create a structure called x to hold our data
	x = READ_ASCII(file, data_start=11)


	;x.field01 contains 15 columns for different types of data
	; and 112 values for each type
	help, x.field01

	;getting the appropriate data out of the structure
	pres = x.field01[1,*]
	temp = x.field01[3,*]
	dew  = x.field01[4,*]


STOP
	;Creating a quick plot

	loadct, 39 ;loading a color table

	plot_title = 'KGRB 00Z, 10 Dec. 2009'
	xtitle = 'Deg. C'
	ytitle = 'Pressure [mb]'

	PLOT, temp, pres, /ylog, yrange = [1000,10], xrange = [-100,0],$
		xtitle = xtitle, ytitle = ytitle, title = plot_title, $
		/nodata
	;Adding some color
	OPLOT, temp, pres, color = 50
	OPLOT, dew,  pres, color = 150

    labels = ['Temp', 'Dew pt.']                                                   
    LEGEND, labels, linestyle = [0,0],  color = [50,150]  $
		,pos=[0.74,0.75,0.91,0.86]

STOP

	;Saving the temp, pressure and dewpt to an IDL .sav file
	SAVE, filename = 'KGRB_00Z.sav', temp, pres, dew, /verbose

	;Saving the variables in an ASCII file
	OPENW, lun2, 'KGRB_00Z.dat',/get_lun
	FOR i=0, N_ELEMENTS(pres)-1 DO 				$
		PRINTF, lun2, pres[i], temp[i], dew[i], $
		FORMAT='(i5,1x,f6.2,1x,f6.2)' 
	FREE_LUN, lun2

STOP
END